REM @echo off
set LIBRARYNAME=Tribler

set PYTHONHOME=C:\Python254
REM Arno: Add .. to make it find khashmir. Add . to find us (python 2.5)
set PYTHONPATH=.;%PYTHONHOME%;..

echo PYTHONPATH SET TO %PYTHONPATH%

set NSIS="C:\Program Files\NSIS\makensis.exe"
REM Diego: what that for? (imagecfg)
set IMGCFG="C:\Program Files\Imagecfg\imagecfg.exe"

REM ----- Check for Python and essential site-packages

IF NOT EXIST %PYTHONHOME%\python.exe (
  echo .
  echo Could not locate Python in %PYTHONHOME%.
  echo Please modify this script or install python [www.python.org]
  exit /b
)

IF NOT EXIST %PYTHONHOME%\Lib\site-packages\wx-*-unicode (
  echo .
  echo Could not locate wxPython in %PYTHONHOME%\Lib\site-packages.
  echo Please modify this script or install wxPython [www.wxpython.org]
  exit /b
)

IF NOT EXIST %PYTHONHOME%\Lib\site-packages\py2exe (
  echo .
  echo Could not locate py2exe in %PYTHONHOME%\Lib\site-packages.
  echo Please modify this script or install wxPython [www.py2exe.org]
  exit /b
)

REM ----- Check for NSIS installer

IF NOT EXIST %NSIS% (
  echo .
  echo Could not locate the NSIS installer at %NSIS%.
  echo Please modify this script or install NSIS [nsis.sf.net]
  exit /b
)

REM ----- Clean up

call clean.bat

REM ----- Build

REM Arno: When adding files here, make sure tribler.nsi actually
REM packs them in the installer .EXE

REM Diego: building the deepest dir we get all of them.
mkdir dist\installdir\bgprocess\Tribler\Images

%PYTHONHOME%\python.exe -O %LIBRARYNAME%\Plugin\Build\Win32\setupBGexe.py py2exe

REM Arno: Move py2exe results to installdir
move dist\*.* dist\installdir\bgprocess
copy %LIBRARYNAME%\Images\SwarmPluginIcon.ico dist\installdir\bgprocess\Tribler\Images
xcopy vlc\* dist\installdir /E /I
REM Diego: replace vlc *.txt with tribler *.txt
del dist\installdir\*.txt
copy %LIBRARYNAME%\*.txt dist\installdir

copy %LIBRARYNAME%\Plugin\Build\Win32\heading.bmp dist\installdir
REM TODO Diego: create .nsi and manifest
copy %LIBRARYNAME%\Plugin\Build\Win32\triblerplugin.nsi dist\installdir
REM TODO Diego : swarmplugin.exe.manifest correct? or axvlc.dll.manifest?
copy %LIBRARYNAME%\Plugin\Build\Win32\swarmplugin.exe.manifest dist\installdir

copy %PYTHONHOME%\Lib\site-packages\wx-2.8-msw-unicode\wx\msvcp71.dll dist\installdir\bgprocess

REM TODO Diego : really needed?
REM copy ffmpeg.exe dist\installdir

copy reset*.bat dist\installdir

cd dist\installdir

:makeinstaller
REM TODO Diego : first test then remove from comments
%NSIS% triblerplugin.nsi
move swarmplugin_*.exe ..
cd ..
cd ..